x265でエンコードするバッチファイル

スポンサーリンク
スポンサーリンク
エンコード

こちらの記事を参考にエンコードの下準備をしておいてください。

スポンサーリンク
スポンサーリンク

必要

avs2pipemod

x265はavsファイルを読み込めないのでパイプで渡します。

avsファイルから偽装wavを取り出すこともできます。

GitHubからダウンロードします。

x265

rigayaの日記兼メモ帳へ行き、右側の「ビルドしたものとか」からダウンロードします。

fawcl

FakeAacWavのコマンドライン版です。
下準備の段階で入っていると思います。

L-SMASH

エンコードした映像と音声をmp4に格納します。

rigayaの日記兼メモ帳へ行き、右側の「ビルドしたものとか」からダウンロードします。
中にあるmuxerとremuxerを使います。

バッチファイル

@echo off

rem 保存先フォルダのパス(""を付けない、\を付ける)
set save=D:\video\

rem プログラムのパス(""を付ける)
set avs2pipemod="C:\Tools\avs2pipemod64.exe"
set x265="C:\Tools\x265.exe"
set fawcl="C:\Tools\fawcl.exe"
set muxer="C:\Tools\muxer.exe"
set remuxer="C:\Tools\remuxer.exe"

rem x265の設定
set x265_opt=--keyint 240 --crf 28 --colormatrix bt709

rem fpsの指定
set fps=24000/1001

rem ループ処理の開始
:loop
if "%~1" == "" goto end

rem エンコードの開始
%avs2pipemod% -y4mp "%~1" | %x265% %x265_opt% - --y4m -o "%save%%~n1.265"
%avs2pipemod% -wav "%~1" > "%save%%~n1.wav"
%fawcl% "%save%%~n1.wav" "%save%%~n1.aac"
%muxer% -i "%save%%~n1.265"?fps=%fps% -o "%save%%~n1_tmp.mp4"
%muxer% -i "%save%%~n1.aac" -o "%save%%~n1.m4a"
%remuxer% -i "%save%%~n1_tmp.mp4" -i "%save%%~n1.m4a" -o "%save%%~n1.mp4"

rem 一時ファイルの削除
del "%save%%~n1.265"
del "%save%%~n1.wav"
del "%save%%~n1.aac"
del "%save%%~n1_tmp.mp4"
del "%save%%~n1.m4a"

shift
goto loop
:end

使い方

テキストエディタに貼り付けて拡張子を.batにして保存してください。

保存先フォルダとプログラムのパスを指定してください。

x265の設定はお好みで。

fpsの指定は音ズレ防止なので、忘れないようにしてください。

avsファイルをバッチファイルにドラッグ&ドロップするとエンコードが始まります。
複数の場合は順番にエンコードされます。

解説

avs2pipemodからx265にパイプで渡してエンコードしています。

avs2pipemodでavsファイルから偽装wavを取り出し、fawclでaacに戻しています。

muxerで映像をmp4に格納しています。

muxerでaacをm4aに格納しています。

remuxerで映像と音声をmp4に格納しています。

コメント

タイトルとURLをコピーしました