x264でエンコードするバッチファイル（qaac版）

必要

x264

rigayaの日記兼メモ帳へ行き、右側の「ビルドしたものとか」からダウンロードします。

qaac

qaacのサイトからqaac_～.zipをダウンロードします。

使用にはApple Application Supportが必要です。
こちらの記事を参考にしてください。

L-SMASH

エンコードした映像と音声をmp4に格納します。

rigayaの日記兼メモ帳へ行き、右側の「ビルドしたものとか」からダウンロードします。
中にあるmuxerとremuxerを使います。

バッチファイル

@echo off

rem 保存先フォルダのパス（""を付けない、\を付ける）
set save=D:\video\

rem プログラムのパス（""を付ける）
set x264="C:\Tools\x264.exe"
set qaac="C:\Tools\qaac64.exe"
set muxer="C:\Tools\muxer.exe"
set remuxer="C:\Tools\remuxer.exe"

rem x264の設定
set x264_opt=--keyint 240 --crf 23 --colormatrix bt709

rem qaacの設定
set qaac_opt=-V 90

rem ループ処理の開始
:loop
if "%~1" == "" goto end

rem エンコードの開始
%x264% %x264_opt% -o "%save%%~n1_tmp.mp4" "%~1"
%qaac% %qaac_opt% "%~1" -o "%save%%~n1.aac"
%muxer% -i "%save%%~n1.aac" -o "%save%%~n1.m4a"
%remuxer% -i "%save%%~n1_tmp.mp4" -i "%save%%~n1.m4a" -o "%save%%~n1.mp4"

rem 一時ファイルの削除
del "%save%%~n1_tmp.mp4"
del "%save%%~n1.aac"
del "%save%%~n1.m4a"

shift
goto loop
:end

使い方

テキストエディタに貼り付けて拡張子を.batにして保存してください。

保存先フォルダとプログラムのパスを指定してください。

x264とqaacの設定はお好みで。

avsファイルをバッチファイルにドラッグ＆ドロップするとエンコードが始まります。
複数の場合は順番にエンコードされます。

解説

x264はavsファイルを読み込めるので、直接渡してエンコードしています。

qaacはavsファイルを読み込めるので、直接渡してエンコードしています。

muxerでaacをm4aに格納しています。

remuxerで映像と音声をmp4に格納しています。