EDCBをビルドするバッチファイル(簡易版)

スポンサーリンク
スポンサーリンク
TS抜き

ビルドしてファイルを配置するバッチファイルです。

スポンサーリンク
スポンサーリンク

VS2019のインストール

こちらの記事を参考にしてください。

バッチファイル

拡張子を.batにして保存します。

x86

@echo off
cd /d %~dp0

for /f "usebackq tokens=*" %%i in (`"%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -latest -products * -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 -property installationPath`) do (
    set InstallDir=%%i
)

call "%InstallDir%\Common7\Tools\VsDevCmd.bat" -no_logo

MSBuild EDCB_ALL.VS2015.sln /nologo /m /t:Rebuild /p:Configuration=Release;Platform=Win32
if errorlevel 1 exit /b 1

cd ..\ini\Tools
MSBuild asyncbuf.vcxproj /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x86
if errorlevel 1 exit /b 1
MSBuild readex.vcxproj /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x86
if errorlevel 1 exit /b 1
MSBuild relayread.vcxproj /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x86
if errorlevel 1 exit /b 1

cd IBonCast
MSBuild IBonCast.sln /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x86
if errorlevel 1 exit /b 1

cd ..\tsidmove
MSBuild tsidmove.sln /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x86
if errorlevel 1 exit /b 1

cd ..\..\..\x86\Release
del /s *.exp *.iobj *.ipdb *.lib *.map *.pdb >nul
copy /v ..\..\Document\*.txt >nul
xcopy /e /v /y ..\..\ini >nul
if not exist BonDriver md BonDriver

cd Tools
copy /v Release\*.exe >nul
copy /v IBonCast\Release\IBonCast.dll .. >nul
copy /v tsidmove\Release\tsidmove.exe >nul
del *.c *.vcxproj
for /d %%i in (*) do rd /s /q %%i

pause

x64

@echo off
cd /d %~dp0

for /f "usebackq tokens=*" %%i in (`"%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -latest -products * -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 -property installationPath`) do (
    set InstallDir=%%i
)

call "%InstallDir%\Common7\Tools\VsDevCmd.bat" -no_logo

MSBuild EDCB_ALL.VS2015.sln /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x64
if errorlevel 1 exit /b 1

cd ..\ini\Tools
MSBuild asyncbuf.vcxproj /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x64
if errorlevel 1 exit /b 1
MSBuild readex.vcxproj /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x64
if errorlevel 1 exit /b 1
MSBuild relayread.vcxproj /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x64
if errorlevel 1 exit /b 1

cd IBonCast
MSBuild IBonCast.sln /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x64
if errorlevel 1 exit /b 1

cd ..\tsidmove
MSBuild tsidmove.sln /nologo /m /t:Rebuild /p:Configuration=Release;Platform=x64
if errorlevel 1 exit /b 1

cd ..\..\..\x64\Release
del /s *.exp *.iobj *.ipdb *.lib *.map *.pdb >nul
copy /v ..\..\Document\*.txt >nul
xcopy /e /v /y ..\..\ini >nul
if not exist BonDriver md BonDriver

cd Tools
copy /v x64\Release\*.exe >nul
copy /v IBonCast\x64\Release\IBonCast.dll .. >nul
copy /v tsidmove\x64\Release\tsidmove.exe >nul
del *.c *.vcxproj
for /d %%i in (*) do rd /s /q %%i

pause

使い方

x86は32bit版、x64は64bit版です。

GitHubからSource code (zip)をダウンロードします。

解凍して「Document」フォルダにバッチファイルを入れます。

バッチファイルをダブルクリックすると処理が始まります。

x86\Release または x64\Release に出力されます。

コメント

タイトルとURLをコピーしました