EDCBをビルドするバッチファイル（簡易版）

TS抜き

2020.08.012024.01.14

ビルドしてファイルを配置するバッチファイルです。

Visual Studioのインストール
バッチファイル
使い方

Visual Studioのインストール

2017以降でビルドできます。

こちらの記事を参考にインストールしてください。

2022で動作確認しています。

バッチファイル

拡張子を.batにして保存します。

@echo off
setlocal
cd /d %~dp0

set OUT_DIR=Document\package

set /p INPUT="1=x86, 2=x64:"
if "%INPUT%" == "1" set ARCH=x86
if "%INPUT%" == "2" set ARCH=x64

for /f "usebackq tokens=*" %%i in (`"%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -latest -products * -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 -property installationPath`) do (
    set VS_INSTALL_DIR=%%i
)
call "%VS_INSTALL_DIR%\Common7\Tools\VsDevCmd.bat" -no_logo

set FRAMEWORK=v4.5
if "%VisualStudioVersion%" == "17.0" set FRAMEWORK=v4.8

if /i "%ARCH%" == "x86" (
    set PLATFORM=Win32
) else (
    set PLATFORM=%ARCH%
)

MSBuild EDCB_ALL.VS2015.sln /nologo /m /t:Build /p:Configuration=Release;Platform=%PLATFORM%;TargetFrameworkVersion=%FRAMEWORK%
if errorlevel 1 exit /b 1
cd ..

pushd ini\Tools
MSBuild misc.sln /nologo /m /t:Build /p:Configuration=Release;Platform=%ARCH%
popd
if errorlevel 1 exit /b 1

pushd ini\Tools\IBonCast
MSBuild IBonCast.sln /nologo /m /t:Build /p:Configuration=Release;Platform=%ARCH%
popd
if errorlevel 1 exit /b 1

pushd ini\Tools\tsidmove
MSBuild tsidmove.sln /nologo /m /t:Build /p:Configuration=Release;Platform=%ARCH%
popd
if errorlevel 1 exit /b 1

set SRC_DIR=%ARCH%\Release
if /i "%ARCH%" == "x86" (
    set SRC_DIR2=Release
) else (
    set SRC_DIR2=%SRC_DIR%
)
set DST_DIR=%OUT_DIR%\%ARCH%

if exist "%DST_DIR%" rd /s /q "%DST_DIR%"
md "%DST_DIR%"
md "%DST_DIR%\BonDriver"
md "%DST_DIR%\EdcbPlugIn"
md "%DST_DIR%\HttpPublic"
md "%DST_DIR%\PostBatExamples"
md "%DST_DIR%\RecName"
md "%DST_DIR%\Tools"
md "%DST_DIR%\Write"

copy /v %SRC_DIR%\*.dll                             "%DST_DIR%" >nul
copy /v %SRC_DIR%\*.exe                             "%DST_DIR%" >nul
copy /v %SRC_DIR%\EdcbPlugIn.tvtp                   "%DST_DIR%\EdcbPlugIn" >nul
copy /v %SRC_DIR%\EpgTimerPlugIn.tvtp               "%DST_DIR%" >nul
copy /v %SRC_DIR%\RecName\RecName_Macro.dll         "%DST_DIR%\RecName" >nul
copy /v %SRC_DIR%\Write\Write_Default.dll           "%DST_DIR%\Write" >nul
copy /v %SRC_DIR%\Write\Write_OneService.dll        "%DST_DIR%\EdcbPlugIn" >nul
copy /v ini\Tools\%SRC_DIR2%\*.exe                  "%DST_DIR%\Tools" >nul
copy /v ini\Tools\IBonCast\%SRC_DIR2%\IBonCast.dll  "%DST_DIR%" >nul
copy /v ini\Tools\tsidmove\%SRC_DIR2%\tsidmove.exe  "%DST_DIR%\Tools" >nul
copy /v ini                                         "%DST_DIR%" >nul
xcopy /e /v ini\HttpPublic                          "%DST_DIR%\HttpPublic" >nul
copy /v ini\PostBatExamples                         "%DST_DIR%\PostBatExamples" >nul
copy /v ini\Tools\*.bat                             "%DST_DIR%\Tools" >nul
copy /v ini\Tools\*.ps1                             "%DST_DIR%\Tools" >nul
copy /v EdcbPlugIn\EdcbPlugIn\ch2chset.vbs          "%DST_DIR%\EdcbPlugIn" >nul
copy /v EdcbPlugIn\EdcbPlugIn\EdcbPlugIn.ini        "%DST_DIR%\EdcbPlugIn" >nul
copy /v EdcbPlugIn\EdcbPlugIn\EdcbPlugIn_Readme.txt "%DST_DIR%\EdcbPlugIn" >nul
copy /v Document\*.txt                              "%DST_DIR%" >nul

pause